×× GetData 方法会调用所有在这个数据环境类里面的 SFCursorAdapter 成员类的 GetData 方法，这样你就不需要自己去一个个的调用它们。与此类似的是，Requery 方法和 Update 方法也会调用每个 SFCursorAdapter 成员类的 Requery 和 Update 方法。
×× 象 SFCursorAdapter 一样，SetConnection 方法会把 DataSource 设置为一个 ADO Recordset，并把这个 Recordset 的 ActiveConnection 属性设置为一个 ADO Connection 对象。不过，它还会调用所有 UseDEDataSource 属性被设置为 .F. 的 SFCursorAdapter 成员类的 SetConnection 方法。
×× 它提供了一些简单的错误处理（cErrorMessage 属性会被填入错误信息）
×× 它有一个 Release 方法。
现在我们看看这个类的一对方法。GetData 非常简单：如果这个数据环境类的任何成员对象拥有 GetData 方法，则调用该方法：
lparameters tlNoData
local loCursor, ;
llReturn
for each loCursor in This.Objects
if pemstatus(loCursor, 'GetData', 5)
llReturn = loCursor.GetData(tlNoData)
if not llReturn
This.cErrorMessage = loCursor.cErrorMessage
exit
endif not llReturn
endif pemstatus(loCursor, 'GetData', 5)
next loCursor
return llReturn
SetConnection 方法稍微复杂一点：如果它的任何成员对象有 SetConnection 方法、并且该成员对象的 UseDEDataSource 属性被设置为 .F.，则调用该成员对象的 SetConnection 方法；然后，如果有任何一个 CursorAdapter 对象的 UseDEDataSource 属性被设置为了 .T.，则使用类似于 SFCusrorAdapter 中的那样的代码来设置自己的 DataSource：
lparameters tuConnection
local llSetOurs, ;
loCursor, ;
llReturn
with This
* Call the SetConnection method of any CursorAdapter that isn't using our
* DataSource.
llSetOurs = .F.
for each loCursor in .Objects
do case
case upper(loCursor.BaseClass) <> 'CURSORADAPTER'
case loCursor.UseDEDataSource
llSetOurs = .T.
case pemstatus(loCursor, 'SetConnection', 5)
loCursor.SetConnection(tuConnection)
endcase
next loCursor
* If we found any CursorAdapters that are using our DataSource, we'll need to
* set our own DataSource.
if llSetOurs
do case
case .DataSourceType = 'ODBC'
.DataSource = tuConnection
case .DataSourceType = 'ADO'
.DataSource = createobject('ADODB.RecordSet')
.DataSource.ActiveConnection = tuConnection
endcase
endif llSetOurs
endwith
TestDE.prg 做了一个演示，它使用 SFDataEnvironment 作为容器，该容器中有一对 SFCursorAdapter 类。因为这个例子用的是 ADO，所以每个 SFCursorAdapter 都需要它自己的 DataSource，因此它们的 UseDEDataSource 属性都被设置成了 .F.（默认设置）。注意：只要简单的调用一下 SFDataEnvironment 的 SetConnection 方法就能搞定为每个 CursorAdapter 设置好 DataSource 属性的事情。
local loConn as ADODB.Connection
loConn = createobject('ADODB.Connection')
loConn.ConnectionString = 'provider=SQLOLEDB.1;data source=(local);' + ;
'database=Northwind;uid=sa;pwd='
&& change password to appropriate value for your database
loConn.Open()
set classlib to SFDataClasses
loDE = createobject('SFDataEnvironment')
with loDE
.AddObject('CustomersCursor', 'SFCursorAdapter')
with .CustomersCursor
.Alias = 'Customers'
.SelectCmd = 'select * from customers'
.DataSourceType = 'ADO'
endwith
.AddObject('OrdersCursor', 'SFCursorAdapter')
with .OrdersCursor
.Alias = 'Orders'
.SelectCmd = 'select * from orders'
.DataSourceType = 'ADO'
endwith
.SetConnection(loConn)
if .GetData()
select Customers
browse nowait
select Orders
browse
else
messagebox('Could not get the data. The error message was:' + ;
chr(13) + chr(13) + .cErrorMessage)
endif .GetData()
endwith
loConn.Close()
可重用数据类
现在我们已经有了可用的 CursorAdapter 和 DataEnvironment 的子类，让我们来谈谈可重用数据类的事情。
一件 VFP 程序员们已经向 Microsoft 要求了很久的事情是可重用数据类。例如，你可能有一个表单和一个报表，它们使用的是完全相同的一套数据，然而你却不得不重复的去手动向数据环境中添加一个个表或者视图——因为数据环境是不可重用的。某些程序员（以及几乎所有的应用程序框架提供商）采用了通过代码来建立可重用数据环境（那时候数据环境是不能可视化的建立子类的）的方法，并且在表单上使用一个 “loader”对象来建立 DataEnvironment 子类的实例。不管怎么说，这种方法总不是那么正规，并且无法用于报表。
现在，在 VFP8 里，我们不仅拥有了建立“能够向任何需要数据的对象提供来自任何数据源的数据”的可重用数据类的能力，还有了建立“能够寄宿数据类的”数据环境类的能力。在我写这篇文章的时候，你还不能在报表中使用 CursorAdapter 或者 DataEnvironment 的子类，不过你可以编程的添加 CursorAdapter 子类（例如把这些代码写在 DataEnvironment 的 INIT 方法中）来利用可重用类的优点。
让我们为 Northwind 数据库的 Customers 和 Orders 表建立一些数据类。CustomersCursor （在 NorthwindDataClasses.vcx 中）是 SFCursorAdapter 的一个子类，其属性如表1：
表 1. CustomersCursor 的属性
属性 值
Alias Customers
CursorSchema CUSTOMERID C(5), COMPANYNAME C(40), CONTACTNAME C(30), CONTACTTITLE C(30), ADDRESS C(60),
CITY C(15), REGION C(15), POSTALCODE C(10), COUNTRY C(15), PHONE C(24), FAX C(24)
KeyFieldList CUSTOMERID
SelectCmd select * from customers
Tables CUSTOMERS
UpdatableFieldList CUSTOMERID, COMPANYNAME, CONTACTNAME, CONTACTTITLE, ADDRESS, CITY, REGION, POSTALCODE, COUNTRY, PHONE, FAX
UpdateNameList CUSTOMERID CUSTOMERS.CUSTOMERID, COMPANYNAME CUSTOMERS.COMPANYNAME, CONTACTNAME CUSTOMERS.CONTACTNAME, CONTACTTITLE CUSTOMERS.CONTACTTITLE, ADDRESS CUSTOMERS.ADDRESS, CITY CUSTOMERS.CITY, REGION CUSTOMERS.REGION, POSTALCODE CUSTOMERS.POSTALCODE, COUNTRY CUSTOMERS.COUNTRY, PHONE CUSTOMERS.PHONE, FAX, CUSTOMERS.FAX
你不会以为我会是手动在属性窗口中输入所有这些属性的值吧？当然不是！我是用 CursorAdapter 的生成器来干的。这里的技巧是打开“Use connection settings in builder only（只使用在生成器中的连接设置）”，填入连接信息以获得一个活动连接，再填好 SelectCMD 以后，最后再用生成器来生成其它的属性设置。
现在，任何时候你需要 Northwind 的 Customers 表中的数据，只要简单的放一个 CustomersCursor 类就够了。当然，我们还没有定义任何连接信息，不过做到这样就已经很不错了，有了这个类就不需要担心怎么获得数据（ODBC、XML、ADO）、使用哪种数据引擎（比如 SQL Server、Access 以及 VFP 8中都有 Northwind 数据库）之类的事情了。
不过，要注意的是这个 Cursor 对付的是 Customers 表中所有的记录。可有时候，你又只想要一个客户的数据。那么，CustomerByIDCursor 是 CustomersCursor 的一个子类，它的 SelectCmd 已经被改成 “Select * from customers where customerid = ?pcustomerid”，还有下面增加的 INIT 方法的代码：
lparameters tcCustomerID
dodefault()
This.AddParmeter('pCustomerID', tcCustomerID)
这段代码会建立一个叫做 pCustomerID 的参数（它跟在 SelectCmd 中指定的是同一个），并且被设置成传递进来的任何值。如果没有值被传递进来的话，那么使用 GetParameter 方法来为这个参数返回一个对象，并在调用 GetData 之前设置它的 value 属性。
OrdersCursor 类类似于 CustomersCursor，只是它返回的是 Orders 表中的所有数据，而 OrdersForCustomerCursor 是它的一个子类，用于返回一个指定客户的所有订单。
责任编辑：小草
